script seen

anda OL pake MIRC bisa jadi bot seen.

jadi kalo kita gak bisa buat bot. ya pakek script ini aja.
mudah aja kok scriptnya. inilah scriptnya :)


ON *:START: {
hmake seen 100
if ($isfile(seen.dat)) { hload seen seen.dat }
}
ON *:EXIT: {
if ($hget(seen)) { hsave -o seen seen.dat }
}
ON *:TEXT:*:#: {
hadd seen $nick text $chan $ctime $1-
if ($1 = .seen) {
if ($2 ison $chan) { .NOTICE $nick $2 dia ada disini tuh. }
else { .NOTICE $nick $nick $+ : $seenparse($2) }
}
}
alias seen {
echo $colour(info) -a *** $seenparse($1)
}
ON *:ACTION:*:#: {
hadd seen $nick act $chan $ctime $1-
}
ON *:QUIT: {
hadd seen $nick quit $ctime $1-
}
on *:PART:#: {
hadd seen $nick part $chan $ctime $1-
}
on *:JOIN:#: {
hadd seen $nick join $chan $ctime $1-
}
ON *:NICK: {
hadd seen $nick nick $newnick $ctime
}
ON *:KICK:#: {
hadd seen $nick kicking $chan $ctime $knick $1-
hadd seen $knick kick $chan $ctime $nick $1-
}
alias -l seenparse {
var %x = $hget(seen,$1)
if (!%x) { return maaf, selama aku join. aku belum liat nick6 $1 join disini :) }
var %n = $1
tokenize 32 %x
if ($1 = text) { return terakir aku lihat %n in $2 $duration($calc($ctime - $3)) yang lalu dengan pesan6 $4- }
if ($1 = act) { return terakir aku lihat %n in $2 $duration($calc($ctime - $3)) yang lalu dengan pesan6 $4- }
if ($1 = quit) { return terakir aku lihat %n keluar $duration($calc($ctime - $2)) yang lalu $iif($3,dengan pesan6 $3-) }
if ($1 = part) { return terakir aku lihat %n pergi dari $2 $duration($calc($ctime - $3)) yang lalu dengan pesan6 $4- }
if ($1 = join) { return terakir aku lihat %n masuk $2 $duration($calc($ctime - $3)) yang lalu. }
if ($1 = nick) { return terakir aku lihat %n ganti nick ke $2 $duration($calc($ctime - $3)) yang lalu. }
if ($1 = kicking) { return terakir aku lihat %n dikick $4 dari $2 $duration($calc($ctime - $3)) yang lalu dengan alasan6 $5- }
if ($1 = kick) { return terakir aku lihat %n dikick dari $2 oleh $4 $duration($calc($ctime - $3)) dengan alasan6 $5- }
}


mudah mudahan ini bermanfaat bagi kita semua. terimakasih :)